Hi,

I want to make a new page where Sign in Button/Widget placed in the center of the page, apart from at the right top tab given in the VT SCADA as attached image.

It will be also best solution for me if I can move that "Sign in" button to anywhere respectively X/Y coordinates with Height and Width in the new page.

Or else, is there any property or widget or script, through which I can make new login/Sign in button or dialog page at the start of the application Like below as reference:
where operator can fill the user-password and that also reflect or connected with the VT SCADA login dialog.!?

Is this something to be used solely when logging in to a client in HTML?

No, I want to use in the start of the SCADA in the runtime...

When SCADA application will start, my application's welcome screen will come as a start screen, in that screen I want to use the Sign In/Login button at the center of that to go further...

In that case I'd suggest you reach out to our Tech Support folks on this. It will require some custom script on the page but shouldn't be much effort. Given your username, I assume you have SupportPlus.

I also need this urgently! it achieved?
@monik.modi@xylem.com

Here is some basic page code to get you going. Note that there are no guarantees that this is the best approach as I am not on the development team. You will also likely want to incorporate some page privileges to limit page access for logged off users:

[
  Title = "/PMfLJ/DR";
  Color = "<FF409FFF>";
  Result = "";
  Username = "";
  Password = "";
  PageX;
  PageY;
  PageHeight = 768;
  PageWidth = 1024;
  PageMinWidth;
  PageMinHeight;
  PageVWidth;
  PageVHeight;
  InputWidth = 150;
  InputHeight = 20;
  ButtonWidth = 150;
  ButtonHeight = 25;
  SecBit = 17;
]

Main [
  Return(Self);

  \System.Edit(PageWidth/2-InputWidth/2, PageHeight/4 { Top left corner - fixed },
              PageWidth/2+InputWidth/2, PageHeight/4+InputHeight { Bottom right corner  }, 
              "Username" { Title }, 
              Username { Var to update } 
              { Remainder of parameters not used, so omitted });

  \System.Edit(PageWidth/2-InputWidth/2, PageHeight/4+InputHeight+50 { Top left corner - fixed },
              PageWidth/2+InputWidth/2, PageHeight/4+2*50+2*InputHeight { Bottom right corner  }, 
              "Password" { Title }, 
              Password { Var to update },
              invalid, invalid, invalid, invalid, invalid, invalid, invalid, invalid, invalid {Optional arguments not set},
              0b000000010000 {Style set to mask input}
              { Remainder of parameters not used, so omitted }); 

  If Winbutton(PageWidth/2-ButtonWidth/2, PageHeight/4+3*50+2*InputHeight, PageWidth/2+ButtonWidth/2, PageHeight/4+2*50+2*InputHeight+ButtonHeight, 0, "Login", 1, \_DialogFont);
  [
    Result = \SecurityManager.QuietLogon(Concat(Username,":",Password));
    Username = "";
    Password = "";
    IfThen(Result == 1,
     Execute(Result=0, 
     \DisplayManager\ShowPage("Overview", 0))
    );
  ]

  {Background Fade}
  GUITransform(0, 768, 1024, 41,
               1, 1, 1, 1, 1 { Scaling              },
               0, 0          { Movement             },
               1, 0          { Visibility, Reserved },
               0, 0, 0       { Selectability        },
               Scope(\Code, "Library", TRUE)\Bitmap(\ImageParmSet("Bitmaps\Lighting Overlays\Transparent\LowerRightToUpperLeftFade.png", "<FFFF40FF>", 0, 0, Invalid, 0.5, 1.4, 1, 0, 1, 0, 0), Invalid, 0, 1, 1, 0.5, 1, 0, 0, 0, 0, 0, "<FFFFFFFF>", 0, 0));
]